From 26899f676f670fe28ae2706c4d72850879021f3d Mon Sep 17 00:00:00 2001
From: Sean Kovacs <kovacsmillio@gmail.com>
Date: Thu, 15 Jan 2026 12:46:01 -0500
Subject: [PATCH] add custom altserver package

---
 home/default.nix               |  5 ++++
 packages/altserver/default.nix | 55 ++++++++++++++++++++++++++++++++++
 packages/overlay.nix           |  1 +
 3 files changed, 61 insertions(+)
 create mode 100644 packages/altserver/default.nix

diff --git a/home/default.nix b/home/default.nix
index 81fdb6b..9bdd2c0 100755
--- a/home/default.nix
+++ b/home/default.nix
@@ -157,10 +157,15 @@
         mosh
         spotify-player
         gh
+        altserver-linux
 
         # development & tooling
         jdk21_headless
         quickemu
+        nerd-fonts.noto
+        noto-fonts
+        noto-fonts-color-emoji
+        nix-prefetch
 
         # kde and kde theming
         kde-rounded-corners
diff --git a/packages/altserver/default.nix b/packages/altserver/default.nix
new file mode 100644
index 0000000..c0ba973
--- /dev/null
+++ b/packages/altserver/default.nix
@@ -0,0 +1,55 @@
+{
+  stdenv,
+  fetchurl,
+  lib,
+}: let
+  sources = {
+    x86_64-linux = {
+      arch = "x86_64";
+      hash = "sha256-C+fDrcaewRd6FQMrO443xdDk/vtHycQ5zWLCOLPqF/s=";
+    };
+    i686-linux = {
+      arch = "i586";
+      hash = "sha256-xxucxefmFOiZn6fgAnKZ6yzxcG+mSpXvLzxlli493EI=";
+    };
+    aarch64-linux = {
+      arch = "aarch64";
+      hash = "sha256-iGAgqkS1DTgiUgUZZ9bsSsNfWggjSIem+Mluc6Xz3ik=";
+    };
+    armv7l-linux = {
+      arch = "armv7";
+      hash = "sha256-99olJlOMEMbZtFILpSRumZUj146IcyD3HrM5AimZPbg=";
+    };
+  };
+
+  source = sources.${stdenv.hostPlatform.system};
+in
+  stdenv.mkDerivation (finalAttrs: {
+    pname = "altserver-linux";
+    version = "0.0.5";
+
+    src = fetchurl {
+      url = "https://github.com/NyaMisty/AltServer-Linux/releases/download/v${finalAttrs.version}/AltServer-${source.arch}";
+      hash = source.hash;
+    };
+
+    dontUnpack = true;
+
+    installPhase = ''
+      runHook preInstall
+      mkdir -p $out/bin
+      cp $src $out/bin/alt-server
+      chmod u+x $out/bin/alt-server
+      runHook postInstall
+    '';
+
+    meta = {
+      homepage = "https://github.com/NyaMisty/AltServer-Linux";
+      description = "AltServer for AltStore, but on-device. Requires root privileges as well as running a custom anisette server currently";
+      license = lib.licenses.agpl3Only;
+      mainProgram = "alt-server";
+      sourceProvenance = with lib.sourceTypes; [binaryNativeCode];
+      platforms = ["x86_64-linux" "i686-linux" "aarch64-linux" "armv7l-linux"];
+      maintainers = with lib.maintainers; [max-amb];
+    };
+  })
diff --git a/packages/overlay.nix b/packages/overlay.nix
index 4a52683..4b0244a 100644
--- a/packages/overlay.nix
+++ b/packages/overlay.nix
@@ -1,4 +1,5 @@
 final: prev: {
   spotify-webapp = final.callPackage ./spotify-webapp {};
   linux-asahi = final.callPackage ./linux-asahi {};
+  altserver-linux = final.callPackage ./altserver {};
 }